上传文件到网站 POST Autohotkey

本文补充说明 :这是源自 Thinkai 博客归档的一个 AutoHotkey v1 示例,演示如何通过 WinHttp.WinHttpRequest.5.1 以 multipart/form-data 方式向服务器 POST 上传文件。

本文补充说明:这是源自 Thinkai 博客归档的一个 AutoHotkey v1 示例,演示如何通过 WinHttp.WinHttpRequest.5.1 以 multipart/form-data 方式向服务器 POST 上传文件。

核心思路:uploadfile() 负责组装参数并发起请求;CreateFormData 类会生成随机 boundary,把普通字段与需要上传的本地文件(upfile)编码为标准 multipart 体,并正确设置 Content-Type;二进制读写依赖 ADODB.Stream(BinArr_FromFile 读文件、BinArr_Join 拼接各段数据)。

基本用法:在服务器端准备好接收文件(示例中对应 upload.php,目标地址为 http://135.230.71.1/upload.php,dst 指定保存路径),然后调用 MsgBox % uploadfile("本地文件路径","服务器保存路径") 即可。

AHK v1 / v2 差异提示:v2 中 ComObjCreate 已改名为 ComObject;IfExist % src 写法被 if FileExist(src) 取代;函数调用与参数传递语法也更统一(无需 %var% 传址包装)。WinHttp 对象模型在两者中基本一致,移植时主要替换 COM 创建与文件存在判断即可。

本脚本来自于Thinkai的博客,仅作为归档。

MsgBox % uploadfile("D:\我的文档\My Music\success.mp3","record\success.mp3")
 
uploadfile(src,dst){
    IfExist % src
    {
        objParam := {"upfile":[src],"dst":dst} ;post数据
        CreateFormData(PostData, hdr_ContentType, objParam)
        whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
        whr.Open("POST", "http://135.230.71.1/upload.php", true) ;地址
        whr.SetRequestHeader("Content-Type", hdr_ContentType)
        whr.Send(PostData)
        whr.WaitForResponse()
        return whr.ResponseText
    }
}
 
CreateFormData(ByRef retData, ByRef retHeader, objParam) {
    New CreateFormData(retData, retHeader, objParam)
}
 
Class CreateFormData {
 
    __New(ByRef retData, ByRef retHeader, objParam) {
 
        CRLF := "`r`n"
 
        ; Create a random Boundary
        Boundary := this.RandomBoundary()
        BoundaryLine := "------------------------------" . Boundary
 
        ; Loop input paramters
        binArrs := []
        For k, v in objParam
        {
            If IsObject(v) {
                For i, FileName in v
                {
                    str := BoundaryLine . CRLF
                         . "Content-Disposition: form-data; name=""" . k . """; filename=""" . FileName . """" . CRLF
                         . "Content-Type: " . this.MimeType(FileName) . CRLF . CRLF
                    binArrs.Push( BinArr_FromString(str) )
                    binArrs.Push( BinArr_FromFile(FileName) )
                    binArrs.Push( BinArr_FromString(CRLF) )
                }
            } Else {
                str := BoundaryLine . CRLF
                     . "Content-Disposition: form-data; name=""" . k """" . CRLF . CRLF
                     . v . CRLF
                binArrs.Push( BinArr_FromString(str) )
            }
        }
 
        str := BoundaryLine . "--" . CRLF
        binArrs.Push( BinArr_FromString(str) )
 
        ; Finish
        retData := BinArr_Join(binArrs*)
        retHeader := "multipart/form-data; boundary=----------------------------" . Boundary
    }
 
    RandomBoundary() {
        str := "0|1|2|3|4|5|6|7|8|9|a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|s|t|u|v|w|x|y|z"
        Sort, str, D| Random
        str := StrReplace(str, "|")
        Return SubStr(str, 1, 12)
    }
 
    MimeType(FileName) {
        n := FileOpen(FileName, "r").ReadUInt()
        Return (n        = 0x474E5089) ? "image/png"
             : (n        = 0x38464947) ? "image/gif"
             : (n&0xFFFF = 0x4D42    ) ? "image/bmp"
             : (n&0xFFFF = 0xD8FF    ) ? "image/jpeg"
             : (n&0xFFFF = 0x4949    ) ? "image/tiff"
             : (n&0xFFFF = 0x4D4D    ) ? "image/tiff"
             : "application/octet-stream"
    }
 
}
 
BinArr_FromString(str) {
    oADO := ComObjCreate("ADODB.Stream")
 
    oADO.Type := 2 ; adTypeText
    oADO.Mode := 3 ; adModeReadWrite
    oADO.Open
    oADO.Charset := "UTF-8"
    oADO.WriteText(str)
 
    oADO.Position := 0
    oADO.Type := 1 ; adTypeBinary
    oADO.Position := 3 ; Skip UTF-8 BOM
    return oADO.Read, oADO.Close
}
 
BinArr_FromFile(FileName) {
    oADO := ComObjCreate("ADODB.Stream")
 
    oADO.Type := 1 ; adTypeBinary
    oADO.Open
    oADO.LoadFromFile(FileName)
    return oADO.Read, oADO.Close
}
 
BinArr_Join(Arrays*) {
    oADO := ComObjCreate("ADODB.Stream")
 
    oADO.Type := 1 ; adTypeBinary
    oADO.Mode := 3 ; adModeReadWrite
    oADO.Open
    For i, arr in Arrays
        oADO.Write(arr)
    oADO.Position := 0
    return oADO.Read, oADO.Close
}
 
BinArr_ToString(BinArr, Encoding := "UTF-8") {
    oADO := ComObjCreate("ADODB.Stream")
 
    oADO.Type := 1 ; adTypeBinary
    oADO.Mode := 3 ; adModeReadWrite
    oADO.Open
    oADO.Write(BinArr)
 
    oADO.Position := 0
    oADO.Type := 2 ; adTypeText
    oADO.Charset  := Encoding
    return oADO.ReadText, oADO.Close
}
 
BinArr_ToFile(BinArr, FileName) {
    oADO := ComObjCreate("ADODB.Stream")
 
    oADO.Type := 1 ; adTypeBinary
    oADO.Open
    oADO.Write(BinArr)
    oADO.SaveToFile(FileName, 2)
    oADO.Close
}

 

声明:本站所有文章,如无特殊说明或标注,均为本站原创发布。任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们进行处理。

给TA捐赠
共{{data.count}}人
人已捐赠
教程

treeview获取选中所有节点信息以及展开 Autohotkey

2020-2-21 15:09:18

教程

中文数字转阿拉伯数字 Autohotkey

2020-2-21 15:10:51

4 条回复 A文章作者 M管理员
  1. doge

    38行可以改成这样
    SplitPath, FileName, justFileName
    str := BoundaryLine . CRLF
    . “Content-Disposition: form-data; name=””” . k . “””; filename=””” . justFileName . “””” . CRLF

  2. doge

    好脚本
    可以用来post (multipart/form-data)文件

  3. aahk

    我感觉用AutoHotkey操作网站文件时功能有点单薄了,我感觉操作网站文件应当采用Delphi或者C++或者JAVA或者Python

❯
个人中心
购物车
优惠劵
今日签到
有新私信 私信列表
搜索