;-------------------------------- ; GUI设置热键的例子 By FeiYue ; ; 注意:第一次按热键可能会不生效 ;-------------------------------- NoEnv Gui
;--------------------------------
; GUI设置热键的例子 By FeiYue
;
; 注意:第一次按热键可能会不生效
;--------------------------------
#NoEnv
Gui, +AlwaysOnTop
Gui, Margin, 15, 15
Gui, Color, DDEEFF
Gui, Font, s12
数量:=9
Loop, % 数量 {
i:=A_Index
;-----------------------
Gui, Add, Text, xm, 触发键
Gui, Add, Edit, x+10 w100 Hwndid
触发键%i%:=控件(id, "触发键" i)
;-----------------------
Gui, Add, Text, x+10, 第二键
Gui, Add, Edit, x+10 w100 Hwndid
第二键%i%:=控件(id, "第二键" i)
;-----------------------
Gui, Add, Text, x+10, 第三键
Gui, Add, Edit, x+10 w100 Hwndid
第三键%i%:=控件(id, "第三键" i)
;-----------------------
Gui, Add, CheckBox, x+10 Hwndid g更新, 开启%i%
开启%i%:=控件(id, "开启" i)
;-----------------------
}
Gui, Show, NA, 游戏辅助 - 热键设置
;-----------------------
Menu, Tray, Click, 1
Menu, Tray, Add
Menu, Tray, Add, 热键设置
Menu, Tray, Default, 热键设置
if (0) {
热键设置:
Gui, Show
return
}
;-----------------------
OnMessage(0x201, "拖动窗口")
拖动窗口() {
if (A_Gui=1 and A_GuiControl="")
SendMessage, 0xA1, 2
}
;-----------------------
读取配置()
OnExit("保存配置")
return
读取配置() {
global
For k,v in 需保存配置的控件
v.g:=v.f
Gosub, 更新
}
保存配置() {
global
For k,v in 需保存配置的控件
v.f:=v.g
}
;-- 每次修改了按键,请先取消选择开启,然后再选择开启
更新:
Critical
Loop, % 数量 {
i:=A_Index
if (k:=触发键%i%.上次)!="" ;-- 先停止上次的热键
Hotkey, % "$" k,, Off UseErrorLevel
if (开启%i%.g) and (k:=触发键%i%.g)!=""
{
触发键%i%.上次:=k, r:=Func("运行").Bind(i) ;-- 利用函数绑定序号
Hotkey, % "$" k, % r, On UseErrorLevel
}
}
Critical, Off
return
运行(i) { ;-- 改为自己的热键循环,按下循环发送,松开停止
global
MsgBox, 4096,, % 触发键%i%.g "--" 第二键%i%.g "--" 第三键%i%.g, 1
}
F1:: ;-- 全部填满并打勾,用于测试
Loop, % 数量
i:=A_Index, 触发键%i%.g:=i, 第二键%i%.g:=i, 第三键%i%.g:=i, 开启%i%.g:=1
Gosub, 更新
return
F2:: Suspend ;-- 挂起热键
F4:: Reload ;-- 重启脚本
控件(id, name) {
global
(!IsObject(需保存配置的控件) && 需保存配置的控件:=[])
需保存配置的控件.Push( obj:=new 控件读写类(id, name) )
return (obj)
}
Class 控件读写类 {
__new(id, name) {
this.id:=id, this.name:=name
}
;-- 用“变量.g”属性来自动读取和写入Gui控件
g[] {
Get {
GuiControlGet, value,, % this.id
return value
}
Set {
GuiControl,, % this.id, % InStr(this.name,"开启")?Round(value):value
return value
}
}
;-- 用“变量.f”属性来自动读取和写入ini配置
f[] {
Get {
IniRead, value, % A_ScriptDir "\set.ini", Set, % this.name, %A_Space%
return value
}
Set {
IniWrite, % value, % A_ScriptDir "\set.ini", Set, % this.name
return value
}
}
}
声明:本站所有文章,如无特殊说明或标注,均为本站原创发布。任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们进行处理。


感谢分享,天天学习