利用ACC和UIA获取文本

;--------------------------------------
;  利用ACC和UIA获取文本  By FeiYue
;--------------------------------------


F9:: Reload


F7::
arr:=ACC获取文本()
MsgBox 4096,, % "Name --> " arr.Name "`n`nText --> " arr.Value
return


F8::
arr:=UIA获取文本()
MsgBox 4096,, % "Name --> " arr.Name "`n`nText --> " arr.Value
return


UIA获取文本(x="", y="")
{
  static UIA:=ComObjCreate("{ff48dba4-60ef-4201-aa87-54103eef594e}"
    , "{30cbe57d-d9d0-452a-ab13-7ac5ac4825ee}")
    , h:=DllCall("LoadLibrary", "Str","oleaut32.dll")
  pos:=(x=""||y="" ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : x&0xFFFFFFFF|y<<32)
  id:=DllCall("WindowFromPoint", "Int64",pos)
  SendMessage, WM_GETOBJECT:=0x3D, 0, 1,, ahk_id %id%
  ;-- UIA.ElementFromPoint == 7
  DllCall(NumGet(NumGet(UIA+0)+7*A_PtrSize), "Ptr",UIA, "Int64",pos, "Ptr*",Element)
  arr:=[], VarSetCapacity(var, 8+2*A_PtrSize), NumPut(8, var, "Short")
  For k, v in { "Name":30005, "Value":30045 }
  {
    ;-- Element.GetCurrentPropertyValue == 10
    DllCall(NumGet(NumGet(Element+0)+10*A_PtrSize),"Ptr",Element,"Int",v,"Ptr",&var)
    arr[k]:=StrGet(pstr:=NumGet(var, 8, "Ptr"), "utf-16")
    DllCall("oleaut32\SysFreeString", "Ptr",pstr)
  }
  ObjRelease(Element)
  return arr
}

ACC获取文本(x="", y="", ByRef Acc="", ByRef child="")
{
  static h:=DllCall("LoadLibrary", "Str","oleacc.dll")
  pos:=(x=""||y="" ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : x&0xFFFFFFFF|y<<32)
  id:=DllCall("WindowFromPoint", "Int64",pos)
  SendMessage, WM_GETOBJECT:=0x3D, 0, 1,, ahk_id %id%
  arr:=[], Acc:=child:="", VarSetCapacity(var,8+2*A_PtrSize,0)
  if DllCall("oleacc\AccessibleObjectFromPoint","Int64",pos,"Ptr*",pacc,"Ptr",&var)=0
  {
    Acc:=ComObjEnwrap(9,pacc,1), child:=NumGet(var,8,"UInt")
    Try arr["Name"]:=Acc.accName(child)
    Try arr["Value"]:=Acc.accValue(child)
    return arr
  }
}