在整个注册表中递归搜索特殊值
; 示例: 用于在整个注册表中
; 递归搜索特殊值的可运行示例.
SetBatchLines -1 ; 让搜索以最快速度进行.
RegSearchTarget = Notepad ; 告知子程序搜索的目标.
Gosub, RegSearch
return
RegSearch:
ContinueRegSearch = y
Loop, Reg, HKEY_LOCAL_MACHINE, KVR
{
Gosub, CheckThisRegItem
if ContinueRegSearch = n ; 这里告知我们要停止搜索.
return
}
Loop, Reg, HKEY_USERS, KVR
{
Gosub, CheckThisRegItem
if ContinueRegSearch = n ; 这里告知我们要停止搜索.
return
}
Loop, Reg, HKEY_CURRENT_CONFIG, KVR
{
Gosub, CheckThisRegItem
if ContinueRegSearch = n ; 这里告知我们要停止搜索.
return
}
; 请注意: 我认为如果已经搜索了 HKEY_USERS, 那么可以不必搜索
; HKEY_CURRENT_USER. 同样地, 如果搜索了 HKEY_LOCAL_MACHINE,
; 那么可以不必搜索 HKEY_CLASSES_ROOT.
return
CheckThisRegItem:
if A_LoopRegType = KEY ; 如果您也想检查键名, 那么移除这两行.
return
RegRead, RegValue
if ErrorLevel
return
IfInString, RegValue, %RegSearchTarget%
{
MsgBox, 4, , The following match was found:`n%A_LoopRegKey%\%A_LoopRegSubKey%\%A_LoopRegName%`nValue = %RegValue%`n`nContinue?
IfMsgBox, No
ContinueRegSearch = n ; 告知我们的调用者停止搜索.
}
return
声明:本站所有文章,如无特殊说明或标注,均为本站原创发布。任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们进行处理。

