ahk实现窗口切换辅助工具

运行后，右键先配置程序，很简单就不详细说了！

#SingleInstance force
#NoEnv
#Persistent

Default:="ahk_class TTOTAL_CMD`nahk_class Chrome_WidgetWin_1`nahk_class SciTEWindow"
setFile:=A_ScriptName ".sav"

Gui +HwndMyGuiHwnd
Gui Add, Text, x5 y10, 切换窗口列表(&L):`n(一行一个ahk辨识窗口特征)
Gui Add, Edit, x5 w245 h120 vWinList, % Default
Gui Add, Button, x5 w75 h23 gSaveFile, 保存(&S)
Gui Add, Button, x90 yp w75 h23 gLoadFile, 读取(&L)
Gui Add, Button, x175 yp w75 h23 gLoadDefault, 默认(&D)
Gui Add, Button, x5 w75 h23 gSaveList, 确定(&O)
Gui Add, Button, x90 yp w75 h23 gCleanList, 清除(&C)
Gui Add, Button, x175 yp w75 h23 gGuiExit, 退出(&X)
Menu, tray, NoStandard
Menu, tray, Add, 配置(&S)`t切换, WinOC
Menu, tray, Add, 退出(&E), GuiExit
Menu, tray, Default, 配置(&S)`t切换
gosub, LoadFile
gosub, SaveList

return

LoadDefault:
    GuiControl,,WinList, % Default
return

SaveFile:
    Gui, Submit, NoHide
    FileDelete, % setFile
    FileAppend, % WinList, % setFile
LoadFile:
    FileRead, OutputVar, % setFile
    GuiControl,, WinList, % OutputVar
    Gui, Submit, NoHide
return

+tab::
    GroupActivate, %GroupName%
return

WinOC:
    IfWinExist, ahk_id %MyGuiHwnd%
        WinHide, ahk_id %MyGuiHwnd%
    else
        Gui, Show, AutoSize
return

CleanList:
    GuiControl,, WinList
    Gui, Submit, NoHide
return

GuiEscape:
GuiClose:
    Gui, Cancel
return

GuiExit:
ExitApp

SaveList:
    Gui, Submit
    Random, NewGroup
    GroupName := "Group" NewGroup
    gps:={}
    loop, Parse, WinList, `n, `r
    {
        if !(winname:=Trim(A_LoopField))
            continue
        GroupAdd, %GroupName%, %winname%
        gps.Insert(winname)
    }
return