【函数】json转码纯ahk实现-feiyue

/* /* ;------------------------------------ ; json转码纯AHK实现 v1.5 By FeiYue ;------------------------------------ */ json2
/*
/*
;------------------------------------
;  json转码纯AHK实现 v1.5  By FeiYue
;------------------------------------
*/

json2obj(s)  ; Json字符串转AHK对象
{
  static rep:={"\""":"""", "\r":"`r", "\n":"`n", "\t":"`t"}
  if !(p:=RegExMatch(s, "[\{\[]", r))
    return
  SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
  obj:=[], stack:=[], arr:=obj, flag:=r, key:="", keyok:=0
  While p:=RegExMatch(s, "\S", r, p+StrLen(r))
  {
    if (r="{" or r="[")       ; 如果是 左括号
    {
      v:=[], (flag="{" ? (arr[key]:=v) : arr.Push(v))
      , stack.Push(arr, flag), arr:=v, flag:=r
      , key:="", keyok:=0, v:=""
    }
    else if (r="}" or r="]")  ; 如果是 右括号
    {
      if !stack.MaxIndex()
        Break
      flag:=stack.Pop(), arr:=stack.Pop(), key:="", keyok:=0
    }
    else if (r=",")           ; 如果是 逗号
    {
      key:="", keyok:=0
    }
    else if (flag="{" and keyok=0)  ; 如果是 键名
    {
      if !(RegExMatch(s, "([^\s:]*)\s*:", r, p)=p)
        Break
      key:=Trim(r1,""""), keyok:=1
    }               ; 如果是 数字、true、false、null
    else if RegExMatch(s, "[\w\+\-\.]+", r, p)=p
    {
      (flag="{" ? (arr[key]:=r) : arr.Push(r))
    }
    else            ; 如果是 字符串
    {
      v:=""
      Loop
      {
        if !(RegExMatch(s, """([^""]*)""", r, p)=p)
          Break, 2
        if !(SubStr(StrReplace(r1,"\\"),0)="\")
          Break
        p+=StrLen(r)-1, v.=r1 . """"
      }
      if InStr(r1:=v . r1, "\")
      {
        r1:=StrReplace(r1, "\\", "\0")
        For k,v in rep
          r1:=StrReplace(r1, k, v)
        r1:=StrReplace(r1, "\0", "\")
      }
      (flag="{" ? (arr[key]:=r1) : arr.Push(r1))
    }
  }
  SetBatchLines, %bch%
  return obj
}

obj2json(obj)  ; AHK对象转Json字符串
{
  static rep:={"\""":"""", "\r":"`r", "\n":"`n", "\t":"`t"}
  if !IsObject(obj)
  {
    if obj is Number
      return obj
    if (obj="true" or obj="false" or obj="null")
      return obj
    obj:=StrReplace(obj, "\", "\\")
    For k,v in rep
      obj:=StrReplace(obj, v, k)
    return """" obj """"
  }
  s:="", arr:=1  ; 是简单数组
  For k,v in obj
    if (k!=A_Index) and !(arr:=0)
      Break
  For k,v in obj
    s.=(arr ? " " : " """ k """ : ") %A_ThisFunc%(v) ",`r`n"
  return (arr ? "[`r`n":"{`r`n")
    . SubStr(s,1,-3) . (arr ? "`r`n]":"`r`n}")
}


s=
(

{
    "name": "BeJson",
    "url": "http://www.bejson.com",
    "page": 88,
    "isNonProfit": true,
    "address":
    {
        "street": "科技园路.",
        "city": "江苏苏州",
        "country": "中国"
    },
    "links":
    [
        {
            "name": "Google",
            "url": "http://www.google.com"
        },
        {
            "name": "Baidu",
            "url": "http://www.baidu.com"
        },
        {
            "name": "SoSo",
            "url": "http://www.SoSo.com"
        }
    ]
}

)

Goto, F1

F1::
t1:=A_TickCount
s:=obj2json(json2obj(s))
t1:=A_TickCount-t1
MsgBox, 4096, %t1% ms, % SubStr(s,1,1000)
return



功能说明

本工具提供纯 AutoHotkey 实现的 JSON 与 AHK 对象互转函数组,方便在脚本里解析或生成 JSON 数据,无需依赖外部库。核心包含两个函数:json2obj() 负责把 JSON 字符串解析为 AHK 关联数组/对象,obj2json() 负责把 AHK 对象序列化为 JSON 字符串。函数兼容嵌套对象、数组、字符串、数字、布尔值(true/false)与 null,并处理了引号、换行、制表符等转义字符,可用于读取配置文件、调用 API 接口返回数据等常见场景。

基本用法

调用方式很简单:先用 json2obj(JSON字符串) 得到 AHK 对象,用 obj["键名"] 或数组索引取值;需要输出时再用 obj2json(对象) 转回 JSON 字符串。作者 FeiYue 附带的示例演示了把一个含中文、布尔值、嵌套对象的 JSON 解析后再序列化的完整流程。

AHK v1 / v2 迁移提示

本实现基于 AutoHotkey v1 语法。若迁移到 AutoHotkey v2,需注意:%A_ThisFunc% 动态函数调用在 v2 中已移除,可改为直接递归调用函数名;SetBatchLines 命令在 v2 中已被 SetBatchLines 内置变量替代;MsgBox, 4096, ..., ... 逗号分隔参数形式在 v2 中需改为函数式调用 MsgBox 文本, "Title", "OK"。此外 v2 已内置部分 JSON 能力,v2.0 环境可优先考虑用官方/社区 JSON 库,更省心且兼容性更好。

声明:本站所有文章,如无特殊说明或标注,均为本站原创发布。任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们进行处理。

给TA捐赠
共{{data.count}}人
人已捐赠
教程

2.5容器-变量

2021-5-30 20:49:59

应用教程

L版本实现多线程找图

2021-6-26 18:49:11

33 条回复 A文章作者 M管理员
  1. xstar

    应该给个预览

  2. kpuppy

    怎么使用呢

  3. 在

    学习下

  4. 水滴石穿

    感谢大佬分享

  5. linuxer

    借鉴一下,大佬果然是先人一步

  6. 薛定谔的猫

    需要借鉴一下思路,大佬果然是先人一步

  7. aahk

    玩的快要成精了

  8. Coffee000

    谢谢分享!!!

  9. Sage

    谢谢分享

  10. yykk

    感谢大佬分享!

  11. dzeanah

    Wish I understood Javascript and JSON more!

  12. lafeir

    json array working?

  13. 独自成俑

    好烦回复可见

  14. ModifierPlus

    Json在网页传输数据时用的多吧,学习一下

  15. Tycho79

    学习一下Json

  16. 素兮若雪

    感谢大佬分享

  17. FM

    进来学习一下,谢谢

  18. user14659

    欣赏欣赏。

  19. 飘缈

    欣赏一下

  20. Gan

    谢谢分享

  21. cnkiller

    feiyue大神的学习一下

  22. 云大卷

    学习

  23. leviathan

    学习一下

  24. 水滴石穿

    学习学习

  25. Tebayaki

    学习学习

  26. 立秋

    666学习一下

  27. 哦哦耶

    谢谢分享

  28. doublezerg

    谢谢分享

  29. daimmon

    学习一下

  30. 見樂

    look look

  31. 慎

    瞧瞧

  32. treefairy

    哪一种格式的json?

  33. Antony

    ?

❯
个人中心
购物车
优惠劵
今日签到
有新私信 私信列表
搜索