【函数】调出文件夹选择对话框

SelectFolder := SelectFolderEx( A_Desktop, "标题栏名称" , 0, "选择文件夹按钮名称" ) Msgbox % SelectFolder SelectFolderEx(StartingFolde
SelectFolder := SelectFolderEx( A_Desktop, "标题栏名称" , 0, "选择文件夹按钮名称" )

Msgbox % SelectFolder

SelectFolderEx(StartingFolder := "", Prompt := "", OwnerHwnd := 0, OkBtnLabel := "") {
   Static OsVersion := DllCall("GetVersion", "UChar")
        , IID_IShellItem := 0
        , InitIID := VarSetCapacity(IID_IShellItem, 16, 0)
                  & DllCall("Ole32.dll\IIDFromString", "WStr", "{43826d1e-e718-42ee-bc55-a1e261c37bfe}", "Ptr", &IID_IShellItem)
        , Show := A_PtrSize * 3
        , SetOptions := A_PtrSize * 9
        , SetFolder := A_PtrSize * 12
        , SetTitle := A_PtrSize * 17
        , SetOkButtonLabel := A_PtrSize * 18
        , GetResult := A_PtrSize * 20
   SelectedFolder := ""
   If (OsVersion < 6) { ; Vista+系统以下, 则恢复使用FileSelectFolder
      FileSelectFolder, SelectedFolder, *%StartingFolder%, 3, %Prompt%
      Return SelectedFolder
   }
   OwnerHwnd := DllCall("IsWindow", "Ptr", OwnerHwnd, "UInt") ? OwnerHwnd : 0
   If !(FileDialog := ComObjCreate("{DC1C5A9C-E88A-4dde-A5A1-60F82A20AEF7}", "{42f85136-db7e-439c-85f1-e4075d135fc8}"))
      Return ""
   VTBL := NumGet(FileDialog + 0, "UPtr")
   ; FOS_CREATEPROMPT | FOS_NOCHANGEDIR | FOS_PICKFOLDERS
   DllCall(NumGet(VTBL + SetOptions, "UPtr"), "Ptr", FileDialog, "UInt", 0x00002028, "UInt")
   If (StartingFolder <> "")
      If !DllCall("Shell32.dll\SHCreateItemFromParsingName", "WStr", StartingFolder, "Ptr", 0, "Ptr", &IID_IShellItem, "PtrP", FolderItem)
         DllCall(NumGet(VTBL + SetFolder, "UPtr"), "Ptr", FileDialog, "Ptr", FolderItem, "UInt")
   If (Prompt <> "")
      DllCall(NumGet(VTBL + SetTitle, "UPtr"), "Ptr", FileDialog, "WStr", Prompt, "UInt")
   If (OkBtnLabel <> "")
      DllCall(NumGet(VTBL + SetOkButtonLabel, "UPtr"), "Ptr", FileDialog, "WStr", OkBtnLabel, "UInt")
   If !DllCall(NumGet(VTBL + Show, "UPtr"), "Ptr", FileDialog, "Ptr", OwnerHwnd, "UInt") {
      If !DllCall(NumGet(VTBL + GetResult, "UPtr"), "Ptr", FileDialog, "PtrP", ShellItem, "UInt") {
         GetDisplayName := NumGet(NumGet(ShellItem + 0, "UPtr"), A_PtrSize * 5, "UPtr")
         If !DllCall(GetDisplayName, "Ptr", ShellItem, "UInt", 0x80028000, "PtrP", StrPtr) ; SIGDN_DESKTOPABSOLUTEPARSING
            SelectedFolder := StrGet(StrPtr, "UTF-16"), DllCall("Ole32.dll\CoTaskMemFree", "Ptr", StrPtr)
         ObjRelease(ShellItem)
   }  }
   If (FolderItem)
      ObjRelease(FolderItem)
   ObjRelease(FileDialog)
   Return SelectedFolder
}

用途说明:这是一个封装好的文件夹选择对话框函数 SelectFolderEx(),可让脚本弹出系统原生的“选择文件夹”对话框,并返回用户选中的文件夹路径。它的优势在于:支持自定义窗口标题、起始文件夹、以及“确定”按钮的文字,比 AHK v1 内置的 FileSelectFolder 更接近现代系统原生体验(在 Windows Vista 及以上调用 IFileDialog,XP 及以下自动回退到 FileSelectFolder)。

基本用法:SelectFolder := SelectFolderEx(A_Desktop, "标题栏名称", 0, "选择文件夹按钮名称"),返回的 SelectFolder 即为所选文件夹路径,若用户取消则为空字符串。

版本提示:本函数为 AHK v1 写法。若迁移到 AHK v2,需将 ComObjCreate 改为 ComObject、NumGet/DllCall 的指针与字符串参数类型按 v2 规范调整(如字符串传 "Str"),并注意 v2 已移除 FileSelectFolder 命令,需改用 DirSelect,或继续沿用本函数基于 COM 的实现。

声明:本站所有文章,如无特殊说明或标注,均为本站原创发布。任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们进行处理。

给TA捐赠
共{{data.count}}人
人已捐赠
函数教程

【函数】利用ACC和UIA后台获取文本 By FeiYue

2021-11-24 8:59:13

教程

飞跃、空等大佬关于dllcall高级应用的精彩阐述整理-dbgba

2021-11-25 8:55:19

0 条回复 A文章作者 M管理员
    暂无讨论,说说你的看法吧
❯
个人中心
购物车
优惠劵
今日签到
有新私信 私信列表
搜索