电脑用小键盘数字键盘九宫格拼音输入法

#NoEnv
SetBatchLines, -1
;设置选项
daduan_mode := 1  ;打断模式，按键切换更快
SetTimer, send_key, 500 ;停留多少毫秒发送，快与稳的取舍
;初始化
SetTimer, send_key, off
array_alpha := {                      "NumpadUp":["a","b","c"], "NumpadPgup":["d","e","f"]
       ,"NumpadLeft":["g","h","i"],"NumpadClear":["j","k","l"],"NumpadRight":["m","n","o"]
    ,"NumpadEnd":["p","q","r","s"], "NumpadDown":["t","u","v"], "NumpadPgdn":["w","x","y","z"]}
SetNumLockState, off
repeat := 0        ;重复的次数
key_send := ""     ;发送的字母
daduan := 0        ;判断repeat被打断
fangan := 1        ;数字键盘映射方案
       
;按键映射
#if fangan  ;方案一：删数回英， 好记符合直觉
NumpadDiv::,   ;左翻页 逗号
NumpadMult::.  ;右翻页 句号
NumpadIns::Space  ;空格上屏;0
NumpadDel::Shift  ;@中英文切换;dot
;NumpadDot::Shift  ;@中英文切换;dot
NumpadSub::BackSpace  ;@退格删除
NumpadAdd::NumLock ;@数字锁，数字选词
NumpadEnter::Enter ;@大enter更通用
#if
#if !fangan  ;方案二：回数删英，常用的按键方便
NumpadDiv::,   ;左翻页
NumpadMult::.  ;右翻页
NumpadIns::Space  ;空格上屏;0
NumpadSub::Enter ;@大enter更通用
NumpadDel::Shift  ;@中英文切换;dot
NumpadEnter::BackSpace  ;@退格删除
NumpadAdd::NumLock ;@数字锁，数字选词
#if

;热键开始：
NumpadUp::
NumpadPgup::
NumpadPgdn::
NumpadEnd::
NumpadDown::
NumpadRight::
NumpadClear::
NumpadLeft::
SetTimer,send_key,off
tips := ""
len_array := array_alpha[A_ThisHotkey].Length()
if(A_ThisHotkey == A_PriorHotkey){
    repeat++
}Else{
	repeat:=1
	if(daduan && daduan_mode){
		send,% key_send
	}
}
loop,% len_array
{
	if(A_Index = repeat)
	    tips .= "【" . array_alpha[A_ThisHotkey][A_Index] . "】  "
	Else
	    tips .= array_alpha[A_ThisHotkey][A_Index] . "  "
}
ToolTip, %tips%, A_CaretX-20, A_CaretY-20
KeyWait, %A_ThisHotkey%
key_send := array_alpha[A_ThisHotkey][repeat]
if(repeat = len_array)
     repeat := 0
daduan := 1
SetTimer,send_key,on
Return

send_key:
ToolTip
daduan := 0
SetTimer,send_key,off
send,% key_send
repeat := 0
Return